FAQ 5.16 How come when I open a file read-write it wipes it out?

Do you have a question? Post it now! No Registration Necessary.  Now with pictures!

This is an excerpt from the latest version perlfaq5.pod, which
comes with the standard Perl distribution. These postings aim to
reduce the number of repeated questions as well as allow the community
to review and update the answers. The latest version of the complete
perlfaq is at http://faq.perl.org .


5.16: How come when I open a file read-write it wipes it out?

    Because you're using something like this, which truncates the file
    *then* gives you read-write access:

            open my $fh, '+>', '/path/name'; # WRONG (almost always)

    Whoops. You should instead use this, which will fail if the file doesn't

            open my $fh, '+<', '/path/name'; # open for update

    Using ">" always clobbers or creates. Using "<" never does either. The
    "+" doesn't change this.

    Here are examples of many kinds of file opens. Those using "sysopen" all
    assume that you've pulled in the constants from "Fcntl":

            use Fcntl;

    To open file for reading:

            open my $fh, '<', $path                               or die $!;
            sysopen my $fh, $path, O_RDONLY                       or die $!;

    To open file for writing, create new file if needed or else truncate old

            open my $fh, '>', $path                               or die $!;
            sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT       or die $!;
            sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666 or die $!;

    To open file for writing, create new file, file must not exist:

            sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT        or die $!;
            sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT, 0666  or die $!;

    To open file for appending, create if necessary:

            open my $fh, '>>' $path                               or die $!;
            sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT      or die $!;
            sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT, 0666 or die $!;

    To open file for appending, file must exist:

            sysopen my $fh, $path, O_WRONLY|O_APPEND              or die $!;

    To open file for update, file must exist:

            open my $fh, '+<', $path                              or die $!;
            sysopen my $fh, $path, O_RDWR                         or die $!;

    To open file for update, create file if necessary:

            sysopen my $fh, $path, O_RDWR|O_CREAT                 or die $!;
            sysopen my $fh, $path, O_RDWR|O_CREAT, 0666           or die $!;

    To open file for update, file must not exist:

            sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT          or die $!;
            sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT, 0666    or die $!;

    To open a file without blocking, creating if necessary:

            sysopen my $fh, '/foo/somefile', O_WRONLY|O_NDELAY|O_CREAT
                or die "can't open /foo/somefile: $!":

    Be warned that neither creation nor deletion of files is guaranteed to
    be an atomic operation over NFS. That is, two processes might both
    successfully create or unlink the same file! Therefore O_EXCL isn't as
    exclusive as you might wish.

    See also the new perlopentut.


The perlfaq-workers, a group of volunteers, maintain the perlfaq. They
are not necessarily experts in every domain where Perl might show up,
so please include as much information as possible and relevant in any
corrections. The perlfaq-workers also don't have access to every
operating system or platform, so please include relevant details for
corrections to examples that do not work on particular platforms.
Working code is greatly appreciated.

If you'd like to help maintain the perlfaq, see the details in

Site Timeline